Mantenere foto, video e altri dati solo sullo smartphone o sul PC è un rischio stupido che meriterebbe le frustate. Nonostante i grandi spazi di archiviazione odierni facciano spesso dimenticare la fragilità dei supporti digitali, è fondamentale scaricare periodicamente i propri file su unità multiple e stabili da tenere in casa. Io ti consiglio di adottare una strategia che ho appena scoperto e che funziona benone: utilizzare due unità USB separate dedicate esclusivamente al backup, e creare un file batch che consenta la funzione di mirroring.
Il Mirroring è preferibile al trascinamento
Quando trascini manualmente i file (per poi eventualmente cliccare per rispondere a Windows che ti chiede se sovrascrivere o ignorare file con nome e estensione uguale), Windows aggiunge i file nuovi e aggiorna/ignora quelli modificati, ma non elimina nulla. Con il tempo, la tua unità di backup si riempirà di file obsoleti che hai già cancellato dall'unità "titolare" (quella su cui lavori ogni giorno), creando disordine e sprecando spazio.
Il metodo del Mirroring, invece, rende l'unità di backup identica all'originale: se hai cancellato un file nell'unità principale, lo script lo cancellerà anche nel backup. Questo garantisce un archivio sempre pulito, ordinato e fedele all'originale.
Automazione per evitare spreco di tempo e energia
Il metodo classico del trascinamento costringe spesso a tornare al PC ogni tanto per controllarne lo stato: può darsi che al copia si interrompa dopo 10 minuti o dopo un'ora perché Windows incontra un file di sistema o un file aperto, e resta così in attesa di un tuo clic per proseguire. Questo comporta il rischio di lasciare il PC acceso per ore inutilmente, che magari si blocca proprio all'inizio del processo. Utilizzando un file batch con il comando Robocopy, la copia non si ferma: lo script salta i file che aoppaiono come problematici (ma che in realtà problematici non sono, vedi sotto) e prosegue fino alla fine senza richiedere il tuo intervento.
Preparazione: Lettere e Unità Esterne
- Assegna lettere fisse: Non usare le prime lettere dell'alfabeto (come D, E o F) perché possono variare se inserisci una penna USB o colleghi un lettore CD/DVD esterno, etc. Usa lettere come Y per l'unità principale e J e K per quelle di backup. Nell'esempio e nello script di seguito darò per scontato che saranno queste le lettere che userai.
Ecco come fare: Clicca con il tasto destro su Start > Gestione disco > Tasto destro sull'unità interessata > "Cambia lettera e percorso di unità". - L’unità "Titolare" esterna: Se il tuo PC ha porte USB-C (riconoscibili dalla linguetta blu), ti suggerisco di tenere anche i dati su cui lavori regolarmente un'unità esterna (lettera Y). Il fatto che l'unità titolare sia esterna ti dà un vantaggio in caso di necessità di riparazione: se devi portare il PC da un tecnico, potrai consegnarlo senza i tuoi dati, proteggendo la tua privacy ed evitando che urti accidentali durante la riparazione danneggino il tuo archivio, e inoltre con quei dati puoi lavorare su un altro PC provvisorio.
- Connessione: Prima di lanciare il backup, collega la prima unità di backup (J) e, se preferisci, anche la seconda (K).
Il Codice Batch
Di seguito do per scontato che le unità esterne di backup abbiano, per il tuo PC, la lettera J e K (a queste si riferisce lo script per la creazione del file batch descritto di seguito).
Copia il testo che vedi nel box qui sotto nel Blocco Note e salvalo ad es. col nome Backup.bat. L'importante è che l'estensione sia bat. Puoi salvarlo nella root dell'unità C: (do per scontato che sia l'unità in cui è installato Windows) e creare un collegamento sul desktop per comodità.
@echo off
set "SORGENTE=Y:"
set "BACKUP_J=J:"
set "BACKUP_K=K:"
set "LOG_J=%~dp0Backup_Log_J.txt"
set "LOG_K=%~dp0Backup_Log_K.txt"
echo ======================================================
echo PROCEDURA DI BACKUP SPECCHIO (MIRROR)
echo ======================================================
echo SORGENTE: UNITA TITOLARE [%SORGENTE%]
echo.
:DISCO_J
if exist %BACKUP_J% (
echo [1/2] Trovata unita Backup J. Inizio sincronizzazione...
robocopy "%SORGENTE%" "%BACKUP_J%" /MIR /R:3 /W:5 /MT:8 /DCOPY:DAT /LOG:"%LOG_J%" /TEE
echo.
echo Backup su J completato con successo.
echo Rimuovi l'unita J e inserisci l'unita K.
pause
goto DISCO_K
) else (
echo ERRORE: Unita J non trovata. Inseriscila per continuare.
pause
goto DISCO_J
)
:DISCO_K
if exist %BACKUP_K% (
echo [2/2] Trovata unita Backup K. Inizio sincronizzazione...
robocopy "%SORGENTE%" "%BACKUP_K%" /MIR /R:3 /W:5 /MT:8 /DCOPY:DAT /LOG:"%LOG_K%" /TEE
echo.
echo Backup su K completato. Procedura terminata.
echo.
shutdown /s /t 60
choice /C SN /T 60 /D S /M "Il PC si spegnera tra 60 secondi. Premere N per annullare"
if errorlevel 2 (
shutdown /a
echo Spegnimento annullato.
pause
exit
)
exit
) else (
echo ERRORE: Unita K non trovata. Inseriscila per completare.
pause
goto DISCO_K
)
$RECYCLE.BIN o System Volume Information. Si tratta di file tecnici di Windows che non riguardano i tuoi dati personali: ignorali tranquillamente.Al termine del backup comparirà una finestra che ti avvertirà dell'imminente spegnimento del PC. Avrai 60 secondi per annullare lo spegnimento. Per farlo potrai cliccare sulla finestra di comando e premere N.
Questo sistema ti permette di gestire backup con il minimo sforzo e con precisione, e soprattutto con una comodità molto maggiore rispetto al classico trascinamento o con l'uso di software aggiuntivi, di fatto non necessari a questo scopo.