In questo articolo utilizzerò il termine "unità" invece della più comune parola "disco". Sebbene Windows (sia 10 che 11) utilizzi ancora spesso la parola "disco" nelle sue finestre di gestione, è una parola tecnicamente impropria per i moderni supporti allo stato solido (SSD), che non contengono alcun disco fisico al loro interno.
Nota: tranne che nel momento di riversaggio dati per il backup è bene tenere queste due unità staccate dal computer, al sicuro (ad es. in un armadio) per ridurre il rischio di danni da malware e danni meccanici.
Il Mirroring è preferibile al trascinamento
Quando trascini manualmente i file (per poi eventualmente cliccare per rispondere a Windows che ti chiede se sovrascrivere o ignorare file con nome e estensione uguale), Windows aggiunge i file nuovi e aggiorna/ignora quelli modificati, ma non elimina nulla. Con il tempo, la tua unità di backup si riempirà di file obsoleti che hai già cancellato dall'unità "titolare" (quella su cui lavori ogni giorno), creando disordine e sprecando spazio.
Il metodo del Mirroring, invece, rende l'unità di backup identica all'originale: se hai cancellato un file nell'unità principale, lo script lo cancellerà anche nel backup. Questo garantisce un archivio sempre pulito, ordinato e fedele all'originale.
Automazione per evitare spreco di tempo e energia
Il metodo classico del trascinamento costringe spesso a tornare al PC ogni tanto per controllarne lo stato: può darsi che al copia si interrompa dopo 10 minuti o dopo un'ora perché Windows incontra un file di sistema o un file aperto, e resta così in attesa di un tuo clic per proseguire. Questo comporta il rischio di lasciare il PC acceso per ore inutilmente, che magari si blocca proprio all'inizio del processo. Utilizzando un file batch con il comando Robocopy, la copia non si ferma: lo script salta i file che appaiono come problematici (ma che in realtà problematici non sono, vedi sotto) e prosegue fino alla fine senza richiedere il tuo intervento.
Preparazione: Lettere delle unità esterne
Assegna lettere fisse alle unità: Non usare le prime lettere dell'alfabeto (come D, E o F) perché possono variare se inserisci una penna USB o colleghi un lettore CD/DVD esterno, etc. Usa lettere come Y per l'unità principale e J e K per quelle di backup. Di seguito darò per scontato che saranno queste le lettere che userai.
Ecco come fare:
- Clicca col tasto destro su Start
- Clicca su Gestione disco
- Clicca col tasto destro sull'unità interessata
- Clicca su "Cambia lettera e percorso di unità"
- Clicca su "Cambia"
- Scegli la lettera dal menù a tendina e clicca "OK"
- Conferma cliccando "Sì"
Attenzione: con questo tipo di assegnazione si ottiene che un certo computer attribuisca una certa lettera a una certa unità, quindi se cambierai computer la su descritta assegnazione dovrà essere ripetuta.
Unità Titolare meglio se esterna: Se il tuo PC ha porte USB abbastanza veloci da non rallentare il tuo lavoro (tipicamente USB 3.0 o versioni successive), ti suggerisco di tenere anche i dati su cui lavori regolarmente un'unità esterna (lettera Y). Il fatto che l'unità titolare sia esterna ti dà un vantaggio in caso di necessità di riparazione: se devi portare il PC da un tecnico, potrai consegnarlo senza i tuoi dati, proteggendo la tua privacy ed evitando che urti accidentali durante la riparazione danneggino il tuo archivio, e inoltre con quei dati puoi lavorare su un altro PC provvisorio.
Connessione: Prima di lanciare il backup, collega la prima unità di backup (J) e, se preferisci, anche la seconda (K).
Il Codice Batch
Di seguito do per scontato che, come nell'esempio sopra, per il tuo PC l'unità titolare abbia la lettera Y e le unità di backup abbiano rispettivamente J e K, come intuitivamente si nota osservando lo script che ti fornisco. Copia il testo che vedi nel box qui sotto nel Blocco Note e salvalo ad es. col nome Backup_Mensile.bat. L'importante è che l'estensione sia bat.
Dove salvare il file: va bene salvarlo ad esempio nella cartella "Documenti" o in una sua sottocartella, o sul desktop. Non salvarlo nella root dell'unità C (do per scontato che Windows sia installato nel drive C), perché per motivi di sicurezza la creazione del file log verrebbe bloccata e con essa anche l'intera operazione.
@echo off
set "SORGENTE=Y:"
set "BACKUP_J=J:"
set "BACKUP_K=K:"
set "LOG_J=%~dp0Backup_Log_J.txt"
set "LOG_K=%~dp0Backup_Log_K.txt"
echo ======================================================
echo PROCEDURA DI BACKUP SPECCHIO (MIRROR)
echo ======================================================
echo SORGENTE: UNITA TITOLARE [%SORGENTE%]
echo.
:DISCO_J
if exist %BACKUP_J% (
echo [1/2] Trovata unita Backup J. Inizio sincronizzazione...
robocopy "%SORGENTE%" "%BACKUP_J%" /MIR /R:3 /W:5 /DCOPY:DAT /XD "$RECYCLE.BIN" "System Volume Information" /LOG:"%LOG_J%" /TEE
echo.
echo Backup su J completato. Rimuovi J e inserisci K.
pause
goto DISCO_K
) else (
echo ERRORE: Unita J non trovato. Inseriscila e premi un tasto.
pause
goto DISCO_J
)
:DISCO_K
if exist %BACKUP_K% (
echo [2/2] Trovata unita Backup K. Inizio sincronizzazione...
robocopy "%SORGENTE%" "%BACKUP_K%" /MIR /R:3 /W:5 /DCOPY:DAT /XD "$RECYCLE.BIN" "System Volume Information" /LOG:"%LOG_K%" /TEE
echo.
echo Backup completato su entrambe le unita.
echo.
shutdown /s /t 60
echo IL PC SI SPEGNERA TRA 60 SECONDI.
echo Per restare acceso, PREMI UN TASTO in questa finestra ora.
pause
shutdown /a
echo Spegnimento annullato. Il PC restera acceso.
pause
exit
) else (
echo ERRORE: Unita K non trovata. Inseriscila e premi un tasto.
pause
goto DISCO_K
)
Quando sarà il momento di eseguire il backup, collegherai al PC le unità J e K (e anche Y se non lo è già) e lancerai il file così creato.
Cosa fa il file batch
Facendo doppio clic sul file batch otterrai la stessa cosa che otterresti se formattassi l'unità di destinazione per poi copiarci sopra tutti i file e tutte le cartelle dell'unità Y (ma otterrai questo molto più velocemente se l'unità di destinazione ha già molti file che non sono da aggiornare).
In altre parole, ecco cosa succederà (di seguito per indicare l'unità di backup scrivo "J", ma vale anche per l'unità "K"):
- I file presenti su Y ma non ancora su J vengono copiati
- I file presenti su entrambe le unità ma diversi per dimensione o data di modifica vengono sovrascritti: vince sempre la versione su Y
- I file presenti su J ma non presenti su Y vengono eliminati (anche la cancellazione di file obsoleti è importante in un aggiornamento)
...Il tutto con due eccezioni: le cartelle "$RECYCLE.BIN" e "System Volume Information" vengono escluse dall'operazione in quanto si tratta di cartelle tecniche di Windows che non contengono tuoi dati.
Durante la copia verranno trasferiti tutti i file e le cartelle dell'unità sorgente, ad eccezione di $RECYCLE.BIN e System Volume Information, che il file batch esclude esplicitamente. Si tratta di cartelle tecniche di Windows che non contengono tuoi dati e che non è necessario includere nel backup.
Dopo l'operazione
Nella cartella dove hai salvato il file batch verranno creati i file Backup_Log_J.txt e Backup_Log_K.txt. Puoi aprirli con il Blocco Note per verificare il resoconto dell'operazione.
Al termine del backup comparirà una finestra che ti avvertirà dell'imminente spegnimento del PC. Avrai 60 secondi per annullare lo spegnimento. Per farlo potrai cliccare sulla finestra di comando e premere un tasto.
Questo sistema ti permette di gestire backup con il minimo sforzo e con precisione, e soprattutto con una comodità molto maggiore rispetto al classico trascinamento o con l'uso di software aggiuntivi, di fatto non necessari a questo scopo.